COMMENT ⊗   VALID 00002 PAGES
C REC  PAGE   DESCRIPTION
C00001 00001
C00002 00002	BEGIN "TEST"
C00004 ENDMK
C⊗;
BEGIN "TEST"
REAL ARRAY RES[1:10];
INTEGER I,J,K,L,BRK;
STRING S,INS1,INS2;
BOOLEAN EOF,FAIL;		COMMENT NEEDED FOR FILE IO;
DEFINE CRLF="'15&'12";		COMMENT A STRING FOR C.R. AND L.F.;
RES[1]←1;
RES[2]←1;
FOR I←3 STEP 1 UNTIL 10 DO 
	RES[I]←RES[I-1]+RES[I-2];
OPEN(1,"DSK",0,0,2,200,BRK,EOF);
	COMMENT CHANNEL,DEVICE,MODE,INBUF,OUTBUF,COUNT,BREAK,END_OF_FILE;
	COMMENT MODE=0 FOR TEXT, '10 FOR BINARY;
	COMMENT INBUF OR OUTBUF, 0 OR 2 IS OK;
ENTER(1,"TEST.DAT",FAIL);
	COMMENT CHANNEL,FILENAME,FAILURE FLAG;
IF FAIL THEN USERERR(0,0,"CAN'T ENTER TEST.DAT");
	COMMENT FIRST TWO ZEROS MAKE THE PROGRAM STOP AND DROP DEAD
		AFTER PRINTING OUT THAT STRING;
INS1←"INS1";
INS2←"INS2";
S←"PLAY;"&CRLF;
OUTSTR(S);
OUT(1,S);
FOR I←0 STEP 1 UNTIL 5 DO
BEGIN "PO"
	S←INS1&"  "&CVS(I)&"  1  "&CVF(RES[10-I]-RES[10-I-1])&";PRINT (P1);"&CRLF;
	OUTSTR(S);	COMMENT `OUTSTR' TYPES OUT A STRING ON THE TTY;
	OUT(1,S);	COMMENT CHAN,STRING - GOES TO THE FILE;
END "PO";		COMMENT DON'T NEED BLOCK NAME HERE, BUT IT HELPS;
S←"FINISH;"&CRLF;
OUTSTR(S);
OUT(1,S);
CLOSE(1);	COMMENT CLOSE(CHANNEL);
RELEASE(1);	COMMENT RELEASE(CHANNEL) - FINISHES UP THE FILE;
END "TEST";